@echo off
REM  RAID800                               
REM  Perl Install tool for RAID800 SVP
REM       All Rights Reserved, Copyright (C) 2020,Hitachi, Ltd. 
REM
REM History  :Version    :DATE        : Coder        : Patch No
REM RAID 800 
REM          :01-00      :2020.01.28  : T.Yamanaka   : #97547 (Strawberry Perl 5.28.2 is supported) 
REM
REM Document
REM Strawberry Perl 5.28.2.1 UnInstaller
REM
REM 

pushd %~dp0
if not exist C:\Strawberry\PerlVer.txt (
  echo Skip the Strawberry Perl uninstallation. :No PerlVer.txt
  goto :Normal_Exit
)

fc PerlVer.txt C:\Strawberry\PerlVer.txt >nul 2>&1
set VER_CHK=%ERRORLEVEL%
if %VER_CHK% equ 0 (
  echo Skip the Strawberry Perl uninstallation. :Match PerlVer.txt
  goto :Normal_Exit
)

for /f "tokens=1-4 delims=," %%a in (C:\Strawberry\PerlVer.txt) do (
  set PerlName=%%a
  set MsiFile=%%b
  set GUID=%%c
  set InsDir=%%d
)

call Msi_UnInstall.bat
set INS_CHK=%ERRORLEVEL%
if %INS_CHK% equ 2 goto :Normal_Exit
if not %INS_CHK% equ 0 goto :Error_Exit

:Normal_Exit
popd
exit /b 0

:Error_Exit
popd
exit /b 1