@echo off

REM   Hitachi SVP
REM  VC++Runtime Install tool for Hitachi SVP
REM       All Rights Reserved, Copyright (C) 2019,Hitachi, Ltd.
REM
REM History  :Version    :DATE        : Coder        : Patch No
REM Hitachi SVP 
REM          :01-00      :2019.08.20  : J.Okuno      : #82714 (Apache2.4.39 is supported) 
REM
REM Document
REM VC++ Runtime v14.16.27027.1 Installer
REM Install the latest version of the VC++Runtime.
REM
REM 

REM **************** Variable settings ****************

REM Folder for log files.
set LOGFILE_FOLDER="C:\vc_runtime_log"
REM Log file path for batch file.
set LOGFILE="%LOGFILE_FOLDER%\vc_runtime_log.txt"
REM Log file path for VC++Runtime exe.
set LOGFILE_RUNTIME_UNINST="%LOGFILE_FOLDER%\vc_runtime_exe_installlog.txt"

REM Name of VC++Runtime install batch.
set NAME_INST_BAT="install_vc_runtime.bat"
REM Full path of VC++Runtime uninstall batch.
set PATH_UNINST_BAT="%~dp0uninstall_vc_runtime.bat"

REM VC++Runtime version to install.
set RUNTIME_VERSION=v14.16.27027.1
REM VC++Runtime folder path to install.
set RUNTIME_FOLDER=%~dp0%RUNTIME_VERSION%

REM **************** Variable settings ****************

REM Make the folder for the log file.
if not exist "%LOGFILE_FOLDER%" (
	mkdir %LOGFILE_FOLDER%
	echo [%date% %time%]Make the folder for the log file. >> %LOGFILE% 2>>&1
)

echo [%date% %time%]%NAME_INST_BAT% Start. >> %LOGFILE% 2>>&1

REM Uninstall VC++Runtime.
call %PATH_UNINST_BAT%
if not %ERRORLEVEL%==0 (
	goto :Error
)

REM Install VC++Runtime silently.
@start /wait /d"%RUNTIME_FOLDER%" vc_redist.x64.exe /norestart /quiet /log %LOGFILE_RUNTIME_UNINST% 2>>&1

REM Install result
if not %ERRORLEVEL%==0 (
	goto :Error
)

echo [%date% %time%]Installed the VC++Runtime %RUNTIME_VERSION%. >> %LOGFILE% 2>>&1

REM Operation successful.
echo [%date% %time%]%NAME_INST_BAT% Successful. >> %LOGFILE% 2>>&1
exit /b 0

:Error
REM Error occured.
echo [%date% %time%]%NAME_INST_BAT% Error. >> %LOGFILE% 2>>&1
echo [%date% %time%]ERRORLEVEL:%ERRORLEVEL% >> %LOGFILE% 2>>&1
echo [%date% %time%]Error occured. >> %LOGFILE% 2>>&1

exit /b %ERRORLEVEL%